最近因為參與一項WEB工程的緣故,寫了一個VBScript的程序，用于配置IIS的虛擬目錄。
特寫出來大家一起分享。

源程序如下：（已在Win2000通過）

strServerName ="localhost"
strRootPath="g:documents" ''虛擬目錄路徑
strVRName="Test" ''虛擬目錄名稱
strDefaultDoc="index.asp" ''起始文檔

Dim objIIS
''MsgBox "IIS://" & strServerName & "/W3SVC/1"

On Error Resume Next
Set objIIS=GetObject("IIS://" & strServerName & "/W3SVC/1")

If err=-2147024893 Then
MsgBox "IIS不存在!" & vbcrlf & "請驗證IIS是否已正確安裝!",vbcritical
Wscript.Quit
ElseIf err<>0 Then
MsgBox "未知錯誤!",vbcritical
Wscript.Quit
End If

On Error GoTo 0

Set objVirtualDir=objIIS.GetObject("IISWebVirtualDir","Root")
For each VR in objVirtualDir
If VR.Name=strVRName Then
MsgBox "虛擬目錄" & strVRName & "已存在!",vbinformation
Wscript.Quit
End If
Next

On Error Resume Next
Set fs=Wscript.CreateObject("Scripting.FileSystemObject")
Set objFolder=fs.GetFolder(strRootPath)

If err=76 Then
MsgBox "路徑" & strRootPath & "不存在!",vbcritical
Wscript.Quit
End If

Set objFolder=nothing
Set fs=nothing
On Error GoTo 0

On Error Resume Next
Set VirDir=objVirtualDir.Create("IISWebVirtualDir",strVRName)
VirDir.AccessRead=true
VirDir.Path=strRootPath
VirDir.DefaultDoc=VirDir.DefaultDoc & "," & strDefaultDoc

VirDir.setInfo

If err<>0 Then
MsgBox "創建虛擬目錄失敗!",vbcritical
Else
MsgBox "虛擬目錄" & strVRName & "成功創建在服務器" & strServerName & "上!",vbinformation
End If

代碼的關鍵在于創建虛擬目錄，及其中的配置：

Set VirDir=objVirtualDir.Create("IISWebVirtualDir",strVRName)
VirDir.AccessRead=true
VirDir.Path=strRootPath
VirDir.DefaultDoc=VirDir.DefaultDoc & "," & strDefaultDoc

VirDir.setInfo